Eskil

apa,bepa,cepa,depa,epa,fepa,gepa
hej,fskdfjshfksdjfhsf,x,hopp,i,lingon,skogen
bluff,spark,torp,kvark,voro,sex,dvargar

apa,bepa,cepa,depa,epa,fepa,gepa
hej,x,fskdfjshfksdjfhsf,hopp,i,lingon,skogen
bluff,spark,torp,kvark,voro,sex,dvargar

##Eskil Plugin : Compare comma separated value (CSV) files

# Example file for a plugin.
# A plugin must start exactly like this one.
# The text after : is the summary you can get at the command line

# This plugin compares CSV files with some preprocessing available

# A plugin must define this procedure to do the job.
# side: left or right
# chi:  An input channel for reading the original file.
# cho:  An output channel for writing the processed file.
proc PreProcess {side chi cho} {
    # Look for parameters in info string
    set opts(-ignore) ""
    set opts(-key) ""
    set opts(-header) 0
    foreach {opt val} $::Info {
        set opts($opt) $val
    }
    # If any column is given by name, assume the file starts with
    # a header line of column names
    foreach col [concat $opts(-ignore) $opts(-key)] {
        if {![string is integer $col]} {
            set opts(-header) 1
        }
    }
    if {$opts(-header)} {
        set nameLine [gets $chi]
        # Keep it first in file
        puts $cho $nameLine
        set nameList [split $nameLine ","]
    }

    set icol {}
    foreach col $opts(-ignore) {
        if {[string is integer $col]} {
            lappend icol $col
        } else {
            lappend icol [lsearch $nameList $col]
        }
    }
    set icol [lsort -integer $icol]

    set kcol {}
    foreach col $opts(-key) {
        if {[string is integer $col]} {
            lappend kcol $col
        } else {
            lappend kcol [lsearch $nameList $col]
        }
    }

    set olines {}
    while {[gets $chi line] >= 0} {
        set items [split $line ","]
        foreach i $icol {
            lset items $i ""
        }
        lappend olines $items
    }
    # Sort on keys
    foreach i [lreverse $kcol] {
        set olines [lsort -index $i $olines]
    }
    foreach items $olines {
        puts $cho [join $items ","]
    }

    # Signal that the file after processing should be used both
    # for comparison and for displaying.
    return 1
}